Raptor

Vi har börjat titta på en strippad version av gamla Raptor. Tanken är att den ska kunna utvecklas på forumet precis som Terminator och Tracker. Raptor bygger på MFI och iden är att ta position när MFI svänger men kliva av när indikatorn når botten eller tak. Det bör gå att få ganska säkra punkter på det viset. Planen är också att bygga in lite smartare money management så att man inte går in igen samma dag om man redan säkrat tex 3-4 punkter vinst.

Scripten postas inom kort i den här tråden, tillsvidare lägger vi med en screenshot på arbetsytan med terminsdiagram och de fyra scripten i varsin editor integrerade direkt i arbetsytan - klart smidigt när man labbar med något!

Här är första utkastet till scripten för en rejält avskalad Raptor. Vi testkör den i veckan och ser hur det fungerar. Tanken är att man bara tar position när innehavet är nollat, alltså ingen vändning av position utan det enda som kan stänga en position är att MFI når taket för Long eller golvet för en Short. Positionen kan alltså ligga över natt. Om man fått en exit innevarande dag går man inte in igen åt samma håll. Däremot är det ok att ta position åt andra hållet om senaste entry skedde tidigare än innevarande dag.


sl) Raptor Long

mval:=mov(mfi(3),4,e)
triglevel:=hhv(aref(mval,1),2)
condition1:=lt(mval,85)
innehav_ok:=eqv(portfolio(v),0)
ej_idag:=gt(int(d),int(lasttrade(s,d)))
öppet=ge(mult(1440,sub(market(c),frac(d))),20)
i30(
draw(mval,2,dysv)
draw(triglevel,3,bsv)
draw(mult(ej_idag,2),5,ksv)
buy1=and(condition1,gt(mval,triglevel))
buy2=and(buy1,innehav_ok)
buy3=and(buy2,gt(h,aref(h,1)))
buy4=and(and(buy3,ej_idag),öppet)
mult(buy4,10)
)



sl) Raptor Short

mval:=mov(mfi(3),4,e)
triglevel:=llv(aref(mval,1),2)
condition1:=gt(mval,15)
innehav_ok:=eqv(portfolio(v),0)
ej_idag:=gt(int(d),int(lasttrade(b,d)))
öppet=ge(mult(1440,sub(market(c),frac(d))),20)
i30(
draw(triglevel,2,rav)
draw(mult(ej_idag,2),3,ksb)
short1=and(condition1,lt(mval,triglevel))
short2=and(short1,innehav_ok)
short3=and(short2,lt(l,aref(l,1)))
short4=and(and(short3,ej_idag),öppet)
mult(short4,10)
)



sl) Raptor exit long
mval:=mov(mfi(3),4,e)
condition1:=gt(mval,99)
innehav_ok:=ge(portfolio(v),0)
öppet:=ge(mult(1440,sub(market(c),frac(d))),20)
i30(
draw(lasttrade(b,p),3,bqb1)
sell1=and(and(condition1,innehav_ok),öppet)
mult(sell1,5)
)


sl) Raptor cover

mval:=mov(mfi(3),4,e)
condition1:=lt(mval,1)
innehav_ok:=le(portfolio(v),0)
öppet:=ge(mult(1440,sub(market(c),frac(d))),20)
i30(
draw(lasttrade(s,p),3,rqb1)
cover1=and(and(condition1,innehav_ok),öppet)
mult(cover1,5)
)

Scripten ovan uppdaterade till den version vi kör nu och loggar signalerna från. Loggen ligger här:

http://www.autostock.se/produkter/raptor

[mikola]

När kommer den att bli nerladdningsbar via Uppdatera standardmodeller?

[Fredrik]

Ursprungligen postat av Rikard Nilsson

Scripten ovan uppdaterade till den version vi kör nu och loggar signalerna från. Loggen ligger här:

http://www.autostock.se/produkter/raptor

Hej! Rikard

Kan man köra OMX Raptor även som triggerscript till bull och bear?

mvh Fredrik

[BRB_67]

Jättebra med fler varianter tillgängliga vilket också ökar motivationen för approved-leverantörerna att utveckla sina koncept så de till slut kanske presterar bättre än gratisvarianterna.

Mvh
Rikard Bengtsson

Ursprungligen postat av mikola

När kommer den att bli nerladdningsbar via Uppdatera standardmodeller?

Förhoppningsvis under dagen.

Ursprungligen postat av Fredrik

Hej! Rikard

Kan man köra OMX Raptor även som triggerscript till bull och bear?

mvh Fredrik

Det borde absolut gå, det kan bli ganska små vinstaffärer ibland så man får tänka på att det bygga in "spread-skydd" så att man inte lägger order i sämsta tänkbara läge för ETFer.

Ursprungligen postat av BRB_67

Jättebra med fler varianter tillgängliga vilket också ökar motivationen för approved-leverantörerna att utveckla sina koncept så de till slut kanske presterar bättre än gratisvarianterna.

Mvh
Rikard Bengtsson

Helt klart hoppas vi att gratisscripten kan vara till nytta för våra programanvändare, och det blir ju samtidigt effekten att kommersiella strategier måste prestera bättre än gratismodeller.

[seadragon]

Ursprungligen postat av Rikard Nilsson

Scripten ovan uppdaterade till den version vi kör nu och loggar signalerna från. Loggen ligger här:

http://www.autostock.se/produkter/raptor

Är det nettopunkter efter courtage?

Nej, det är brutto men vi redovisar antal signaler så att man själv kan räkna ut exakt vad det ger. I Efterbörsen kommer vi däremot redovisa nettopunkter precis som för övriga strategier.

[Berra]

Ursprungligen postat av Rikard Nilsson

Scripten ovan uppdaterade till den version vi kör nu och loggar signalerna från. Loggen ligger här:

http://www.autostock.se/produkter/raptor

Ser spännande ut har testat lite i AT8-bänken ser väldigt bra ut. Men Rikard hur ska ordermodellerna se ut? En liten anvisning känner lite undran över "cover" tex.
Berra, kan meddela oxå att det var F-secure som var problemet inte min hårddisk men nu fungerar det igen./

Haa.. jag ser nu att frågan var lite sen...!!! trodde jag skulle behöva göra själv, detta blir ju ännu mycket bättre.

[NickoTrader]

Trevligt med nya script!

Rikard, är inte b och s skiftade, i scripten för long/short ovan, i "ej_idag". I alla fall verkar det så i jämförelse med din screendump.

Har för övrigt beställt en större skärm - många fönster blir det
Mvh

Jo, jag hade fel i screenshoten, scripten ska tillåtas ta position åt andra hållet en gång samma dag.

[jimmy]

Hej Rikard,

vad blev statistiken idag?


/J

Köpsignal på 1098 och positionen ligger kvar. Har lagt till en takeprofit också, vi lägger ut scripten igen imorgon. Ett filter ska dit också som blockerar ev signal första minuterna efter öppning.

Dagens handel med Raptor avklarad, och +9 punkter inkl positionen som öppnades igår. Scripten ser ut så här: (slå på visning av volymfält för att se MFI-kurvan)


mval:=mov(mfi(3),4,e)
triglevel:=hhv(aref(mval,1),2)
condition1:=lt(mval,85)
innehav_ok:=eqv(portfolio(v),0)
ej_idag:=gt(int(d),int(lasttrade(s,d)))
öppet:=ge(mult(1440,sub(market(c),frac(d))),20)
datum_ok:=eqv(int(d),int(date()))
inpådagen:=Gt(Frac(d),0.376)
i30(
draw(mval,2,dysv)
draw(triglevel,3,bsv)
draw(mult(ej_idag,2),5,ksv)
buy1=and(condition1,gt(mval,triglevel))
buy2=and(buy1,innehav_ok)
buy3=and(buy2,gt(h,aref(h,1)))
buy4=and(and(and(and(buy3,ej_idag),öppet),datum_ok),inpådagen)
mult(buy4,10)
)



mval:=mov(mfi(3),4,e)
triglevel:=llv(aref(mval,1),2)
condition1:=gt(mval,15)
innehav_ok:=eqv(portfolio(v),0)
ej_idag:=gt(int(d),int(lasttrade(b,d)))
öppet:=ge(mult(1440,sub(market(c),frac(d))),20)
datum_ok:=eqv(int(d),int(date()))
inpådagen:=Gt(Frac(d),0.376)
i30(
draw(triglevel,2,rav)
draw(mult(ej_idag,2),3,ksb)
short1=and(condition1,lt(mval,triglevel))
short2=and(short1,innehav_ok)
short3=and(short2,lt(l,aref(l,1)))
short4=and(and(and(and(short3,ej_idag),öppet),datum_ok),inpådagen)
mult(short4,10)
)




high:=cmpref(h,1,a)
low:=cmpref(l,1,a)
tplevel:=div(sub(high,low),2)
takeprofit:=gt(c,add(tplevel,lasttrade(b,p)))
mval:=mov(mfi(3),4,e)
condition1:=gt(mval,99)
innehav_ok:=gt(portfolio(v),0)
öppet:=ge(mult(1440,sub(market(c),frac(d))),20)
datum_ok:=eqv(int(d),int(date()))
inpådagen:=Gt(Frac(d),0.376)
i30(
draw(add(lasttrade(b,p),tplevel),2,dgqb2)
draw(lasttrade(b,p),3,bqb)
sell1=and(and(or(takeprofit,condition1),innehav_ok),öppet)
sell2=and(and(sell1,datum_ok),inpådagen)
mult(sell2,5)
)

{@A(0,)}




high:=cmpref(h,1,a)
low:=cmpref(l,1,a)
tplevel:=div(sub(high,low),2)
takeprofit:=lt(c,sub(lasttrade(s,p),tplevel))
mval:=mov(mfi(3),4,e)
condition1:=lt(mval,1)
innehav_ok:=lt(portfolio(v),0)
öppet:=ge(mult(1440,sub(market(c),frac(d))),20)
datum_ok:=eqv(int(d),int(date()))
inpådagen:=Gt(Frac(d),0.376)
i30(
draw(sub(lasttrade(s,p),tplevel),2,mqb2)
draw(lasttrade(s,p),3,rqb)
cover1=and(and(or(takeprofit,condition1),innehav_ok),öppet)
cover2=and(and(cover1,datum_ok),inpådagen)
mult(cover2,5)
)

{@A(0,)}